Arshes
日本語

シェーダー仕様

目次

Arshes のエフェクトのシェーダーを書くためのリファレンスです。シェーダーはSlangで書きます。属性と解像度のマクロは arshes.slang で定義されています。

エントリポイント

Fragment

エントリポイントです。UV(0.0〜1.0)か独自の VertexOutput を受け取り、RGBA を返します。

[shader("fragment")]
float4 fragmentMain(float2 uv : TEXCOORD) : SV_Target {
    return float4(uv, 0.0, 1.0);
}

Vertex(任意)

[primitive(type, count)] と組み合わせて書く、独自の頂点シェーダーです。既定の全画面の四角形を置き換えます。

struct VertexOutput {
    float4 position : SV_Position;
    float4 color : COLOR;
};

[primitive(4, 1000)]
[shader("vertex")]
VertexOutput vertexMain(uint vid : SV_VertexID, uint iid : SV_InstanceID) {
    Particle p = particles[iid];
    // vid: 0~3 (quad corners)
    // iid: 0~999 (which particle)
}

Compute(任意)

フラグメントより前に、宣言した順で実行されます。コンピュートシェーダーは複数宣言できます。スレッド数は [dispatch] と [numthreads] で指定します。テクスチャは SampleLevel(samp, uv, 0) でサンプリングしてください。Sample() は iOS ではレベル 0 として動きますが、Android では ComputeDerivativeGroupQuadsKHR ケーパビリティが必要で、ほとんどの端末は対応していません。

uniform float microphone;

struct State {
    float value;
};

[size(1)]
RWStructuredBuffer<State> state;

[dispatch(1, 1, 1)]
[numthreads(1, 1, 1)]
[shader("compute")]
void computeMain(uint3 id : SV_DispatchThreadID) {
    state[0].value = lerp(state[0].value, microphone, 0.1);
}

組み込みの uniform

エンジンが用意する値とテクスチャです。下記の名前のとおりに宣言すると、自動で結び付けられます。

time

シェーダーが始まってからの経過時間(秒)です。再コンパイルで 0 に戻ります。

uniform float time;

deltaTime

前のフレームからの経過時間(秒)です。

uniform float deltaTime;

frame

シェーダーが始まってからのフレーム数です。再コンパイルで 0 に戻ります。

uniform int frame;

resolution

描画の解像度(幅, 高さ)をピクセルで表します。int のマクロ RESOLUTION_X/Y も使えます。

uniform float2 resolution;

cameraTex

カメラの RGB テクスチャです。リニア色空間で、カラーグレーディングは掛かっていません。フィルター(カラーグレーディング)と sRGB への変換は、エフェクトの後に適用されます。

uniform Texture2D<float3> cameraTex;

depthTex

深度テクスチャです。使えるかどうかは端末によります。大きさは int のマクロ DEPTH_RESOLUTION_X / DEPTH_RESOLUTION_Y で取得できます。

uniform Texture2D<float> depthTex;

backbuffer

前のフレームのバッファです。

uniform Texture2D<float4> backbuffer;

blueNoiseTex

256x256、1 チャンネルのブルーノイズテクスチャです。ノイズを崩さないように、.Load(int3(px % 256, py % 256, 0)) でテクセルをそのまま読んでください(サンプラーの補間を通さない)。256x256 の境界をまたいでタイル状に並べられます。

uniform Texture2D<float> blueNoiseTex;

sampler

テクスチャのサンプリングに使うサンプラーステートです。名前は自由に付けられます。

uniform SamplerState sampler;

microphone

マイク入力の音量(RMS)です。0.0 から 1.0 の値を取ります。

uniform float microphone;

touch

タッチ入力です。xy は位置で、左上が (0,0)、右下が (1,1) です。z は触れている間 1.0、離すと 0.0 になります。xy は離した後も最後の位置を保ち、最初に触れるまでは (-1,-1) です。

uniform float3 touch;

cameraPosition

カメラのワールド座標です。この uniform を宣言すると、カメラが AR モードに切り替わります。

uniform float3 cameraPosition;

invViewMatrix

カメラのビュー行列の逆行列です。この uniform を宣言すると、カメラが AR モードに切り替わります。

uniform float4x4 invViewMatrix;

invProjectionMatrix

カメラの射影行列の逆行列です。この uniform を宣言すると、カメラが AR モードに切り替わります。

uniform float4x4 invProjectionMatrix;

読み書きできるリソース

自分で宣言する、フレームをまたいで内容が保持されるリソースです。名前は自由に付けられます。

RWStructuredBuffer

フレームをまたいで保持される、読み書き可能なバッファです。独自の構造体を使えます。要素数は [size(N)] で指定します。

[size(4)]
RWStructuredBuffer<float4> state;

RWTexture2D

フレームをまたいで保持される、読み書き可能な 2D テクスチャです。[size2d(w, h)] は必須で、大きさを指定します。名前の末尾が「RW」のとき、その「RW」を除いた名前で Texture2D を宣言すると、同じテクスチャを読み取り専用で参照します。サンプラーを使いたい場合に使用します。要素型が float のとき、iOS は 32 bit float、Android は 16 bit float で保持します。

[size2d(RESOLUTION_X, RESOLUTION_Y)]
RWTexture2D<float4> canvasRW;

// read-only view of canvasRW
Texture2D<float4> canvas;

属性

[range(min, max, default)]

uniform の float / int をスライダーとして表示します。

[range(0.0, 1.0, 0.5)]
uniform float brightness;

[rgb(r, g, b)]

uniform の float3 をカラーピッカーとして表示します。色は sRGB で指定し、シェーダーに渡る前にリニアへ自動で変換されます(エフェクトはリニア空間で動きます)。そのため、選んだ色がそのままの見た目で出ます。

[rgb(1.0, 0.0, 0.0)]
uniform float3 tintColor;

[rgba(r, g, b, a)]

uniform の float4 を、アルファつきのカラーピッカーとして表示します。RGB は sRGB で指定し、リニアへ自動で変換されます。アルファは変換されません。

[rgba(1.0, 1.0, 1.0, 0.5)]
uniform float4 bgColor;

[toggle(default)]

uniform の bool をトグルとして表示します。

[toggle(true)]
uniform bool useEffect;

[size(N)]

RWStructuredBuffer の要素数を指定します。既定は 1 です。

[size(64)]
RWStructuredBuffer<float4> particles;

[size2d(w, h)]

RWTexture2D の大きさを指定します。画面に合わせるなら RESOLUTION_X/Y、深度に合わせるなら DEPTH_RESOLUTION_X/Y を使います。

[size2d(RESOLUTION_X / 2, RESOLUTION_Y / 2)]
RWTexture2D<float4> canvas;

[dispatch(x, y, z)]

コンピュートシェーダーのスレッドグループ数を指定します。スレッドの総数は dispatch × numthreads です。

[dispatch(RESOLUTION_X / 8, RESOLUTION_Y / 8, 1)]
[numthreads(8, 8, 1)]
[shader("compute")]
void computeMain(uint3 id : SV_DispatchThreadID) { }

[primitive(type, count)]

独自の頂点シェーダーが描く形状を定義します。type はプリミティブあたりの頂点数(1 = 点、3 = 三角形、4 = 四角形)、count はインスタンス数です。

[primitive(4, 1000)]
[shader("vertex")]
VertexOutput vertexMain(uint vid : SV_VertexID, uint iid : SV_InstanceID) {
    // vid: 0~3 (quad corners), iid: 0~999 (particle index)
}

[pass(index)]

マルチパスの描画を定義します。パスは順番に描画されます(パス 0 は画面を消去し、1 以降は前の結果を残します)。最大 8 パスです。

[pass(0)]
[shader("fragment")]
float4 background(float2 uv : TEXCOORD) : SV_Target {
    return float4(uv, 0.5, 1.0);
}

[pass(1)]
[primitive(3, 1)]
[shader("vertex")]
VertexOutput triVert(uint vid : SV_VertexID, uint iid : SV_InstanceID) { ... }

[pass(1)]
[shader("fragment")]
float4 triangle(VertexOutput input) : SV_Target {
    return input.color;
}

[blend(blendMode)]

ブレンドモードを指定します。BlendMode.None(上書き)、BlendMode.Additive(src + dst)、BlendMode.Alpha(通常のアルファブレンド)があります。

[blend(BlendMode.Alpha)]
[shader("fragment")]
float4 overlay(float2 uv : TEXCOORD) : SV_Target {
    float d = length(uv - 0.5);
    float alpha = smoothstep(0.3, 0.2, d);
    return float4(1.0, 0.5, 0.0, alpha);
}